Franck-Hertz Experiment

f[x_]:=(E^(-(((x-.168))^2)))Erfc[10(x-.168)]

F[x_]:=f[.4(x-4.9)]+1.5f[.3(x-9.8)]+2.5f[.3(x-14.7)]+3.5f[.3(x-19.6)]

elec[v_]:=Dynamic[Refresh[Table[Text[Style["→",18,Bold,Yellow],{RandomReal[{-3.25,3}],RandomReal[{-.8,.8}],RandomReal[{-1,1}]}],{n,1,IntegerPart[4F[v]+1]}],UpdateInterval->1]]

tube[v_]:=Graphics3D[{Gray,Opacity[.1],Cylinder[{{-5,0,0},{5,0,0}},2],Gray,Opacity[.3],Cuboid[{3.5,-.8,-1},{3.53,.8,1}],Pink,Opacity[1],Cuboid[{-3.5,-.8,-1},{-3.47,.8,1}],Black,Opacity[1],Table[{Line[{{.5,y,-z},{.5,y,z}}],Line[{{.5,-y,z},{.5,y,z}}]},{y,-1.25,1.25,.25},{z,-1.25,1.25,.25}],Thickness[.008],Line[{{-3.5,0,-3.5},{3.5,0,-3.5}}],Line[{{.5,0,-1.25},{.5,0,-3.5}}],Line[{{-3.5,0,-1},{-3.5,0,-3.5}}],Line[{{3.5,0,-1},{3.5,0,-3.5}}],elec[v],Table[Text[Style["∣",24,Background->White],{x,0,-3.5}],{x,-1.85,-1.05,.40}],Table[Text[Style["\[VerticalSeparator]",24],{x,0,-3.5}],{x,-1.65,-.85,.40}],Text[Style["○",40],{2.5,0,-3.55}],Text[Style["●",32,White],{2.52,0,-3.5}],Text[Style["A",20],{2.5,0,-3.5}],Text[Style["\[VerticalSeparator]",24,Background->White],{1,0,-3.5}],Text[Style["∣",24],{1.2,0,-3.5}],
Text[Style["-",20,Red,Bold],{-3.5,0,1.75}],Text[Style["-",20,Red,Bold],{3.5,0,1.75}],Text[Style["+",20,Black,Bold],{.25,0,1.75}]},ViewPoint->{2,-4,3},Boxed->False,ImageSize->{600,200}]

signal[v_]:=Plot[F[x],{x,0,v},PlotRange->{{0,16},{0,6}},PlotStyle->{Thick,Green},Frame->True,FrameTicks->{Automatic,None},FrameLabel->{Style["grid voltage (V)",18],Style["ammeter current",18]},ImageSize->{600,250}]

Manipulate[
Column[{
tube[v],
signal[v]
}],
{{v,4,"voltage (V)"},.01,16,Appearance->"Labeled"},
ControlPlacement->Top,TrackedSymbols:>{v},SaveDefinitions->True]

CAPTION

This experiment carried out by James Franck and Gustav Ludwig Hertz in 1914 was intended to support Niels Bohr's model of the atom, according to which electrons occupy discrete energy levels that can absorb or emit energy in only certain quantized amounts.

In a tube containing mercury vapor at low pressure, a heated cathode emits electrons, which are accelerated by a positively-charged grid and collected at the anode. The anode is at a slightly negative potential relative to the grid, so that electrons require a small amount of kinetic energy to reach it after passing through the grid. The electrons undergo elastic collisions with the mercury atoms and are detected at the anode until the grid potential is increased to approximately 4.9 volts. At this point, the anode current decreases precipitously. This is attributed to the collisions becoming inelastic, as the electron kinetic energy excites mercury atoms to the lowest available excited state. This energy difference agrees well with the 254 nm transition in the emission spectrum of mercury.

As the grid potential is further increased, this behavior recurs at 9.8 and 14.7 volts, multiples of 4.9 volts, as the electrons are able to excite two or more mercury atoms.

Franck and Hertz were awarded the 1925 Nobel Prize in Physics for this work.

DETAILS

Snapshot 1: the current increases as the grid voltage is increased

Snapshot 2: until approximately 4.9 volts, when the current drops

Snapshot 3: this recurs at multiples of 4.9 volts

Reference: Wikipedia, "Franck–Hertz Experiment."

THIS NOTEBOOK IS THE SOURCE CODE FROM

"Franck-Hertz Experiment" from the Wolfram Demonstrations Project
 https://demonstrations.wolfram.com/FranckHertzExperiment/

Contributed by: S. M. Blinder

A full-function Wolfram Mathematica system (Version 6 or higher) is required to edit this notebook.
GET WOLFRAM MATHEMATICA »

© Wolfram Demonstrations Project & Contributors   |   Terms of Use   |   Make a new version of this Demonstration »