Wavepacket for a Free Particle

a[Δp_,t_]:=(1/(4(Δp)^2))+I(t/2);
b[p0_,Δp_,x_]:=(p0/(2(Δp)^2))+I x;
c[p0_,Δp_]:=-((p0^2)/(4(Δp)^2)) (*Auxiliary quantities*)

Ψ[p0_,Δp_,x_,t_]:=(2π (Δp)^2 4a[Δp,t]^2)^(-1/4)(E^(c[p0,Δp]+b[p0,Δp,x]^2/(4a[Δp,t]))) (*Wave packet corresponding to an initial Gaussian wavefunction*)

Prob[p0_,Δp_,x_,t_]:=Ψ[p0,Δp,x,t]Conjugate[Ψ[p0,Δp,x,t]] (*Probability density*)

F[p0_,Δp_,x_,t_,j_]:={Re[Ψ[p0,Δp,x,t]],Im[Ψ[p0,Δp,x,t]],Prob[p0,Δp,x,t]}[[j]](*Choice of function to be plotted*)

k[p0_,Δp_,n_]:=p0+(n-3)Δp (*Characteristic momenta*)

ReΨ[p0_,Δp_,x_,t_,n_]:=(1/(Sqrt[2π]))(2π(Δp)^2)^(-1/4)(E^(-(k[p0,Δp,n]-p0)^2/(2 Δp)^2))Cos[k[p0,Δp,n]x-k[p0,Δp,n]^2/2 t]+(n-3) 2(1/(Sqrt[2π]))(2π(Δp)^2)^(-1/4) (*Real part of the characteristic harmonic waves (raised for easier visibility)*)

Fmin[Δp_,j_]:={-(2π/(2 Δp)^2)^(-1/4),-(2π/(2 Δp)^2)^(-1/4),-(2π/(2 Δp)^2)^(-1/2)/50}[[j]](*Lower limit of the vertical axis*)

Fmax[Δp_,j_]:={(2π/(2 Δp)^2)^(-1/4),(2π/(2 Δp)^2)^(-1/4),(2π/(2 Δp)^2)^(-1/2)}[[j]](*Upper limit of the vertical axis*)

tmax=50;

Manipulate[If[j<4,Plot[F[p0,Δp,x,t,j],{x,-Max[(4/(Δp)),p0  tmax],Max[(4/(Δp)),p0  tmax]},PlotRange->{Fmin[Δp,j],Fmax[Δp,j]},Epilog->{PointSize[Large],Point[{p0 t,0}]},ImageSize->{500,350}],Plot[{ReΨ[p0,Δp,x,t,1],ReΨ[p0,Δp,x,t,2],ReΨ[p0,Δp,x,t,3],ReΨ[p0,Δp,x,t,4],ReΨ[p0,Δp,x,t,5]},{x,-Max[(4/(Δp)),p0  tmax],Max[(4/(Δp)),p0  tmax]},Epilog->{PointSize[Medium],Point[Table[{k[p0,Δp,n]/2t,(1/(Sqrt[2π]))(2π(Δp)^2)^(-1/4)((n-3) 2+(E^(-(k[p0,Δp,n]-p0)^2/(2 Δp)^2)))},{n,1,5}]]},Axes->{True,True},ImageSize->{500,350}]],
{{p0,1,"average momentum, <p>"},0,1,Appearance->"Labeled"},{{Δp,.1,"momentum uncertainty, Δp"},.1,1,Appearance->"Labeled"},
{{t,0,"time"},0,tmax,Appearance->"Labeled"},{{j,1,"function"},{1->"Re Ψ(x,t)",2->"Im Ψ(x,t)",3->"P(x,t)",4->"five partial waves"}},
SaveDefinitions->True]

CAPTION

In general, the wavefunction of a free particle is a superposition of infinitely many harmonic waves. In this Demonstration the probability distribution of momenta is assumed to be a Gaussian with average <p> and standard deviation Δp. The Demonstration allows you to follow the time evolution of the real and imaginary parts of the wavefunction, of the probability distribution function, and of (the real part of) the five partial harmonic waves corresponding to p=<p>+k Δp, k=-2,-1,0,1,2. The circle in the wavefunction and probability distribution plots shows the positions of a classical particle moving with momentum p = < p >. The circle on the crest of each partial harmonic wave moves with the respective phase velocity. Units: ℏ=1, m=1.

THIS NOTEBOOK IS THE SOURCE CODE FROM

Andrés Santos

"Wavepacket for a Free Particle"
 https://demonstrations.wolfram.com/WavepacketForAFreeParticle/
 Wolfram Demonstrations Project
 Published: January 15, 2009

A full-function Wolfram Mathematica system is required to edit this notebook.
GET WOLFRAM MATHEMATICA »

© Wolfram Demonstrations Project & Contributors   |   Terms of Use   |   Make a new version of this Demonstration »